templates: add a minimal flake-parts template

templates/minimal-flake-parts/.gitignore

@@ -0,0 +1,2 @@
+result
+.direnv/

templates/minimal-flake-parts/checks.nix

@@ -0,0 +1,22 @@
+{ self, ... }:
+{
+  perSystem =
+    {
+      self',
+      lib,
+      system,
+      ...
+    }:
+    {
+      checks =
+        let
+          nixosMachines = lib.mapAttrs' (
+            name: config: lib.nameValuePair "nixos-${name}" config.config.system.build.toplevel
+          ) ((lib.filterAttrs (_: config: config.pkgs.system == system)) self.nixosConfigurations);
+
+          packages = lib.mapAttrs' (n: lib.nameValuePair "package-${n}") self'.packages;
+          devShells = lib.mapAttrs' (n: lib.nameValuePair "devShell-${n}") self'.devShells;
+        in
+        nixosMachines // packages // devShells;
+    };
+}

templates/minimal-flake-parts/clan.nix

@@ -0,0 +1,11 @@
+{ inputs, ... }:
+{
+  imports = [
+    inputs.clan.flakeModules.default
+  ];
+  clan = {
+    specialArgs = {
+      inherit inputs;
+    };
+  };
+}

templates/minimal-flake-parts/devshells.nix

@@ -0,0 +1,17 @@
+_: {
+  perSystem =
+    {
+      pkgs,
+      inputs',
+      ...
+    }:
+    {
+      devShells = {
+        default = pkgs.mkShellNoCC {
+          packages = [
+            inputs'.clan.packages.default
+          ];
+        };
+      };
+    };
+}

templates/minimal-flake-parts/flake.nix

@@ -0,0 +1,30 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+
+    clan.url = "git+https://git.clan.lol/clan/clan-core?shallow=1";
+    clan.inputs.nixpkgs.follows = "nixpkgs";
+    clan.inputs.flake-parts.follows = "flake-parts";
+
+    flake-parts.url = "github:hercules-ci/flake-parts?shallow=1";
+    flake-parts.inputs.nixpkgs-lib.follows = "nixpkgs";
+
+  };
+
+  outputs =
+    inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } (
+      { ... }:
+      {
+        systems = [
+          "x86_64-linux"
+        ];
+
+        imports = [
+          ./checks.nix
+          ./clan.nix
+          ./devshells.nix
+        ];
+      }
+    );
+}