yadunut.dev/flake.nix

{
  description = "yadunut.dev website";
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils = {
      url = "github:numtide/flake-utils";
    };
    zig = {
      url = "github:mitchellh/zig-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    zls = {
      url = "github:zigtools/zls";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      zig,
      zls,
      flake-utils,
      ...
    }:
    let
      overlays = [
        (final: prev: {
          zigpkgs = zig.packages.${prev.system};
          zlspkgs = zls.packages.${prev.system};
        })
      ];
    in
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit overlays system; };
        zig = pkgs.zigpkgs."0.15.1";
        zls = pkgs.zlspkgs.zls.overrideAttrs (prev: {
          nativeBuildInputs = [ zig ];
        });
        zineBinary =
          if system == "aarch64-darwin" then
            pkgs.stdenvNoCC.mkDerivation {
              pname = "zine";
              version = "0.11.1";
              src = pkgs.fetchzip {
                url = "https://github.com/kristoff-it/zine/releases/download/v0.11.1/aarch64-macos.zip";
                sha256 = "WKY9B4ObE4D7fkvMsF3cLvGHyxOT2FI8YNwLmOAujrQ=";
                stripRoot = false;
              };
              installPhase = ''
                mkdir -p $out/bin
                cp $src/zine $out/bin/
                chmod +x $out/bin/zine
              '';
            }
          else
            { };
      in
      {
        devShells = {
          default = pkgs.mkShell {
            buildInputs = [
              zig
              zls
              zineBinary
            ];
          };
        };
      }
    );
}