{ nixpkgs, self, lib }:
{ directory  # The directory containing the machines subdirectory
, specialArgs ? { } # Extra arguments to pass to nixosSystem i.e. useful to make self available
, machines ? { } # allows to include machine-specific modules i.e. machines.${name} = { ... }
}:
let
  machinesDirs = lib.optionalAttrs (builtins.pathExists "${directory}/machines") (builtins.readDir (directory + /machines));

  machineSettings = machineName:
    lib.optionalAttrs (builtins.pathExists "${directory}/machines/${machineName}/settings.json")
      (builtins.fromJSON
        (builtins.readFile (directory + /machines/${machineName}/settings.json)));

  nixosConfiguration = { system ? "x86_64-linux", name }: nixpkgs.lib.nixosSystem {
    modules = [
      self.nixosModules.clanCore
      (machineSettings name)
      (machines.${name} or { })
      {
        clanCore.machineName = name;
        clanCore.clanDir = directory;
        # TODO: remove this once we have a hardware-config mechanism
        nixpkgs.hostPlatform = lib.mkDefault system;
      }
    ];
    inherit specialArgs;
  };

  nixosConfigurations = lib.mapAttrs
    (name: _:
      nixosConfiguration { inherit name; })
    (machinesDirs // machines);

  systems = [
    "x86_64-linux"
    "aarch64-linux"
    "riscv64-linux"
    "x86_64-darwin"
    "aarch64-darwin"
  ];

  clanInternals = {
    machines = lib.mapAttrs
      (name: _:
        (builtins.listToAttrs (map
          (system:
            lib.nameValuePair system (nixosConfiguration { inherit name system; })
          )
          systems))
      )
      (machinesDirs // machines);
  };
in
{ inherit nixosConfigurations clanInternals; }